ovcc-sig-queue.vala 2.51 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111
/* 
 * 
 * Copyright (C) 2011 Colomban Wendling <ban@herbesfolles.org>
 *                    Jonathan Michalon <studios.chalmion@no-log.org>
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
 * 
 */

public class OVCC.SigQueue
{
  private struct Entry {
    Object  obj;
    ulong   id;
  }
  
  private SList<Entry?> list = null;
  
  /**
   * Add a signal to the list
   * 
   * @param obj The object on which the signal is registered
   * @param id The signal ID
   */
  public void add (Object obj,
                   ulong  id)
  {
    Entry e = {obj, id};
    
    list.prepend (e);
  }
  
  /* disconnects an entry */
  private bool disconnect (Entry e)
  {
    if (SignalHandler.is_connected (e.obj, e.id)) {
      e.obj.disconnect (e.id);
      return true;
    } else {
      warning ("trying to disconnect a non-existent signal");
      return false;
    }
  }
  
  /* removes an entry */
  private bool remove_entry (Entry e)
  {
    bool removed = disconnect (e);
    list.remove (e);
    
    return removed;
  }
  
  /**
   * Removes all signals in the list that are owned by @obj
   * 
   * @param obj The object to remove from the list
   * @return The count of removed signals
   */
  public uint remove_object (Object obj)
  {
    var n = 0;
    foreach (var e in list) {
      if (e.obj == obj) {
        remove_entry (e);
        n ++;
      }
    }
    return n;
  }
  
  /**
   * Removes a signal from the list, and disconnect it.
   * 
   * @param obj The object owning the signal
   * @param id The signal ID
   * @return whether the signal was disconnected
   */
  public bool remove (Object  obj,
                      ulong   id)
  {
    foreach (var e in list) {
      if (e.obj == obj && e.id == id) {
        return remove_entry (e);
      }
    }
    return false;
  }
  
  /**
   * Removes all signals in the list.
   */
  public void remove_all ()
  {
    foreach (var e in list) {
      disconnect (e);
    }
    list = null;
  }
}